import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

group = "dev.fyloz.colorrecipesexplorer"
version = "5.2.1"

plugins {
    kotlin("jvm") version "1.5.21"
    id("org.jetbrains.dokka") version "1.5.0"
    id("maven-publish")
    id("com.github.johnrengelman.shadow") version "6.1.0"
}

repositories {
    mavenCentral()
}

dependencies {
    implementation("org.liquibase:liquibase-core:4.3.1")

    // Logging
    implementation("io.github.microutils:kotlin-logging:1.12.5")
    implementation("org.slf4j:slf4j-api:1.7.30")
    implementation("ch.qos.logback:logback-classic:1.0.13")

    runtimeOnly("mysql:mysql-connector-java:8.0.22")

    testImplementation("io.mockk:mockk:1.10.6")
    testImplementation("io.kotest:kotest-runner-junit5:4.4.1")
}

publishing {
    publications {
        create<MavenPublication>("cre-database-manager") {
            from(components["kotlin"])
        }
    }

    repositories {
        maven {
            url = uri("https://archiva.fyloz.dev/repository/internal/")
            name = "Archiva"

            credentials {
                username = System.getenv("ARCHIVA_USERNAME")
                password = System.getenv("ARCHIVA_PASSWORD")
            }
        }
    }
}

tasks.test {
    useJUnitPlatform()

    testLogging {
        events("failed")
    }

    reports {
        junitXml.isEnabled = true
        html.isEnabled = false
    }
}

tasks.withType<KotlinCompile>() {
    kotlinOptions.jvmTarget = "11"
    kotlinOptions.useIR = true
}

tasks.withType<Jar> {
    manifest {
        attributes["Main-Class"] = "dev.fyloz.colorrecipesexplorer.databasemanager.DatabaseUpdaterKt"
    }
}

tasks.dokkaHtml {
    outputDirectory.set(rootDir.resolve("dokka"))
}