Database-Manager/build.gradle.kts

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

group = "dev.fyloz.colorrecipesexplorer"
version = "6.1"

plugins {
    kotlin("jvm") version "1.6.20"
    id("org.jetbrains.dokka") version "1.6.10"
    id("maven-publish")
    id("com.github.johnrengelman.shadow") version "7.1.2"
}

repositories {
    mavenCentral()
}

dependencies {
    implementation("org.liquibase:liquibase-core:4.9.0")

    // Logging
    implementation("io.github.microutils:kotlin-logging:2.1.21")
    implementation("org.slf4j:slf4j-api:1.7.36")
    implementation("ch.qos.logback:logback-classic:1.2.11")

    runtimeOnly("mysql:mysql-connector-java:8.0.28")

    testImplementation("io.mockk:mockk:1.12.3")
    testImplementation("io.kotest:kotest-runner-junit5:5.2.2")
    testImplementation("io.kotest:kotest-framework-datatest:5.2.2")
}

publishing {
    publications {
        create<MavenPublication>("cre-database-manager") {
            from(components["kotlin"])
        }
    }

    repositories {
        maven {
            url = uri("https://archiva.fyloz.dev/repository/internal/")
            name = "Archiva"

            credentials {
                username = System.getenv("ARCHIVA_USERNAME")
                password = System.getenv("ARCHIVA_PASSWORD")
            }
        }
    }
}

tasks.test {
    useJUnitPlatform()

    testLogging {
        events("failed")
    }

    reports {
        junitXml.isEnabled = true
        html.isEnabled = false
    }
}

tasks.withType<KotlinCompile>() {
    kotlinOptions.jvmTarget = "11"
}

tasks.withType<Jar> {
    manifest {
        attributes["Main-Class"] = "dev.fyloz.colorrecipesexplorer.databasemanager.DatabaseUpdaterKt"
    }
}

tasks.dokkaHtml {
    outputDirectory.set(rootDir.resolve("dokka"))
}