Backend/build.gradle.kts

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

group = "dev.fyloz.colorrecipesexplorer"

val kotlinVersion = "1.5.21"
val springBootVersion = "2.3.4.RELEASE"

plugins {
    // Outer scope variables can't be accessed in the plugins section, so we have to redefine them here
    val kotlinVersion = "1.5.21"
    val springBootVersion = "2.3.4.RELEASE"

    id("java")
    id("org.jetbrains.kotlin.jvm") version kotlinVersion
    id("org.jetbrains.dokka") version "1.4.32"
    id("org.springframework.boot") version springBootVersion
    id("org.jetbrains.kotlin.plugin.spring") version kotlinVersion
    id("org.jetbrains.kotlin.plugin.jpa") version kotlinVersion
}

repositories {
    mavenCentral()

    maven {
        url = uri("https://archiva.fyloz.dev/repository/internal")
    }
}

dependencies {
    implementation(platform("org.jetbrains.kotlin:kotlin-bom:${kotlinVersion}"))
    implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk8:${kotlinVersion}")
    implementation("org.jetbrains.kotlin:kotlin-reflect:${kotlinVersion}")
    implementation("com.fasterxml.jackson.module:jackson-module-kotlin:2.11.3")
    implementation("javax.xml.bind:jaxb-api:2.3.0")
    implementation("io.jsonwebtoken:jjwt:0.9.1")
    implementation("org.apache.poi:poi-ooxml:4.1.0")
    implementation("org.apache.pdfbox:pdfbox:2.0.4")
    implementation("dev.fyloz.colorrecipesexplorer:database-manager:5.2.1")

    implementation("org.springframework.boot:spring-boot-starter-data-jpa:${springBootVersion}")
    implementation("org.springframework.boot:spring-boot-starter-jdbc:${springBootVersion}")
    implementation("org.springframework.boot:spring-boot-starter-web:${springBootVersion}")
    implementation("org.springframework.boot:spring-boot-starter-validation:${springBootVersion}")
    implementation("org.springframework.boot:spring-boot-starter-security:${springBootVersion}")
    implementation("org.springframework.boot:spring-boot-configuration-processor:${springBootVersion}")
    implementation("org.springframework.boot:spring-boot-devtools:${springBootVersion}")

    testImplementation("org.springframework:spring-test:5.1.6.RELEASE")
    testImplementation("org.mockito:mockito-inline:3.12.4")
    testImplementation("com.nhaarman.mockitokotlin2:mockito-kotlin:2.2.0")
    testImplementation("org.junit.jupiter:junit-jupiter-api:5.7.2")
    testImplementation("io.mockk:mockk:1.12.0")
    testImplementation("org.springframework.boot:spring-boot-starter-test:${springBootVersion}")
    testImplementation("org.springframework.boot:spring-boot-test-autoconfigure:${springBootVersion}")
    testImplementation("org.jetbrains.kotlin:kotlin-test:${kotlinVersion}")

    runtimeOnly("com.h2database:h2:1.4.199")
    runtimeOnly("mysql:mysql-connector-java:8.0.22")
    runtimeOnly("org.postgresql:postgresql:42.2.16")
    runtimeOnly("com.microsoft.sqlserver:mssql-jdbc:9.2.1.jre11")

    implementation("org.springframework.cloud:spring-cloud-starter:2.2.8.RELEASE")
}

springBoot {
    buildInfo()
}

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

sourceSets {
    main {
        java
        kotlin
    }
    test {
        kotlin
    }
}

tasks.test {
    reports {
        junitXml.required.set(true)
        html.required.set(false)
    }

    useJUnitPlatform()
    testLogging {
        events("skipped", "failed")
    }
}

tasks.withType<JavaCompile>() {
    options.compilerArgs.addAll(arrayOf("--release", "11"))
}
tasks.withType<KotlinCompile>().all {
    kotlinOptions {
        jvmTarget = JavaVersion.VERSION_11.toString()
        freeCompilerArgs = listOf(
            "-Xopt-in=kotlin.contracts.ExperimentalContracts",
            "-Xinline-classes"
        )
    }
}

tasks.dokkaHtml {
    outputDirectory.set(rootDir.resolve("dokka"))
}